?******************************************************
? Problem Set 5
? Tutorial for Microeconometrics
? Summer term 2008
? Katrin Sommerfeld
?******************************************************

options crt;
freq N;
read  (file='L:\Microeconometrics\experiment.raw') treated age educ black mar nodegree re74 re75 re78 hisp ;

?******************************************************
? 1. Descriptive Statistics
title 'All';
msd(terse) treated age educ black mar nodegree re74 re75 hisp;

select treated=0;
title 'Only Non-Participants';
msd(terse) treated age educ black mar nodegree re74 re75 hisp;
select 1;

select treated=1;
title 'Only Participants';
msd(terse) treated age educ black mar nodegree re74 re75 hisp;
select 1;
?stop;

? t-test, here done for real income 1974
select treated=0;
msd(terse) re74;
set mean0=@mean;
set s0=@stddev;
set n0=@nob;
select 1;

select treated=1;
msd(terse) re74;
set mean1=@mean;
set s1=@stddev;
set n1=@nob;
select 1;

set t=(mean1-mean0)/sqrt(s1**2/n1 - s0**2/n0);
print t;

? t-tests in a loop for all variables:
dot age educ nodegree mar black hisp re74 re75 ;
	select treated=0;
	msd(terse) . ;
	set mean0=@mean;
	set s0=@stddev;
	set n0=@nob;
	select 1;
	
	select treated=1;
	msd(terse) . ;
	set mean1=@mean;
	set s1=@stddev;
	set n1=@nob;
	select 1;
	
	set t=(mean1-mean0)/sqrt(s1**2/n1 - s0**2/n0);
	print t;
enddot;


?******************************************************
? 2. Probit für random assignment
probit treated c age educ nodegree mar black hisp re74 re75 ;


?******************************************************
? 3. Average Treatment Effect = ATE
select treated=0;
msd(terse) re78;
set mean_0=@mean;
select 1;

select treated=1;
msd(terse) re78;
set mean_1=@mean;
select 1;

title 'Average Treatment Effect = ATE';
set ATE=mean_1-mean_0;
print ATE;

?***************************************************
? Diff-in-Diff estimator
title 'Differences-in-Differences estimator';
select treated=1;
msd (terse) re75 re78;
set yt0=@mean(1);
set yt1=@mean(2);
select 1;

select treated=0;
msd (terse) re75 re78;
set yc0=@mean(1);
set yc1=@mean(2);
select 1;

set did=(yt1-yt0)-(yc1-yc0);
print did;

end;